Em Perl, como posso iterar sobre o produto cartesiano de vários conjuntos?
-
12-09-2019 - |
Pergunta
Dada número x
de matrizes, cada uma com um número possivelmente diferente de elementos, como posso percorrer todos combinações onde eu selecionar um item de cada matriz?
Exemplo:
[ ] [ ] [ ]
foo cat 1
bar dog 2
baz 3
4
Retorna
[foo] [cat] [ 1 ]
[foo] [cat] [ 2 ]
...
[baz] [dog] [ 4 ]
Estou fazendo isso em Perl, btw.
Solução 3
recursiva e exemplos Perl mais fluentes (com comentários e documentação) para fazer o produto cartesiano pode ser encontrada em http://www.perlmonks.org/?node_id=7366
Exemplo:
sub cartesian {
my @C = map { [ $_ ] } @{ shift @_ };
foreach (@_) {
my @A = @$_;
@C = map { my $n = $_; map { [ $n, @$_ ] } @C } @A;
}
return @C;
}
Outras dicas
módulo Set :: CrossProduct faz exatamente o que você quer. Note-se que você não está realmente à procura de permutações, que é a ordenação dos elementos de um conjunto. Você está procurando o produto cruzado, que são as combinações de elementos de diferentes conjuntos.
Meu módulo dá-lhe um iterador, para que você não criar tudo na memória. Você cria uma nova tupla somente quando você precisar dele.
use Set::Crossproduct;
my $iterator = Set::CrossProduct->new(
[
[qw( foo bar baz )],
[qw( cat dog )],
[qw( 1 2 3 4 )],
]
);
while( my $tuple = $iterator->get ) {
say join ' ', $tuple->@*;
}
A solução recursiva simples para um número arbitrário de listas:
sub permute {
my ($first_list, @remain) = @_;
unless (defined($first_list)) {
return []; # only possibility is the null set
}
my @accum;
for my $elem (@$first_list) {
push @accum, (map { [$elem, @$_] } permute(@remain));
}
return @accum;
}
solução A não tão simples não-recursivo para um número arbitrário de listas:
sub make_generator {
my @lists = reverse @_;
my @state = map { 0 } @lists;
return sub {
my $i = 0;
return undef unless defined $state[0];
while ($i < @lists) {
$state[$i]++;
last if $state[$i] < scalar @{$lists[$i]};
$state[$i] = 0;
$i++;
}
if ($i >= @state) {
## Sabotage things so we don't produce any more values
$state[0] = undef;
return undef;
}
my @out;
for (0..$#state) {
push @out, $lists[$_][$state[$_]];
}
return [reverse @out];
};
}
my $gen = make_generator([qw/foo bar baz/], [qw/cat dog/], [1..4]);
while ($_ = $gen->()) {
print join(", ", @$_), "\n";
}
Há um método Pensei primeiro que usa um par de loops e sem recursão.
- encontrar o número total de permutações
- ciclo de 0 a total_permutations-1
- observar que, tomando o índice de ciclo módulo o número de elementos em uma matriz, você pode obter cada permutações
Exemplo:
Dada a [3], B [2], C [3],
for (index = 0..totalpermutations) {
print A[index % 3];
print B[(index / 3) % 2];
print C[(index / 6) % 3];
}
em que é claro para um ciclo pode ser substituído de varrer [A B C ...], e uma pequena parte pode ser memoized. Claro, a recursividade é mais puro, mas isso pode ser útil para línguas em que a recursividade é severamente limitada pelo tamanho da pilha.
Você pode usar loops aninhados.
for my $e1 (qw( foo bar baz )) {
for my $e2 (qw( cat dog )) {
for my $e3 (qw( 1 2 3 4 )) {
my @choice = ($e1, $e2, $e3);
...
}}}
Quando você precisa de um número arbitrário de loops aninhados, você pode usar Algorithm :: Loops 's NestedLoops
.
use Algorithm::Loops qw( NestedLoops );
my @lists = (
[qw( foo bar baz )],
[qw( cat dog )],
[qw( 1 2 3 4 )],
);
my $iter = NestedLoops(\@lists);
while ( my @choice = $iter->() ) {
...
}