Como posso obter a lista de propriedades em um objeto no ActionScript?

Question

Eu tenho um dataprovider e uma filterfunction para minha matriz que é atribuído ao meu dataprovider.

Como posso obter uma lista das propriedades que estão em cada linha da dataprovider (item.data) como ele é passado para o filterfunction?

Por exemplo, se o meu objeto contido:

• Objeto
  • nome
  • e-mail
  • endereço

Então eu gostaria, na minha filterfunction para ser capaz de olhar para o nome, email e endereço. Infelizmente, eu não sei o que essas propriedades serão antes da mão.

Todas as idéias?

Answer 1

Se é um objeto dinâmico Eu acredito que você pode apenas fazer algo como isto:

var obj:Object; // I'm assuming this is your object

for(var id:String in obj) {
  var value:Object = obj[id];

  trace(id + " = " + value);
}

Isso é como ele é feito em AS2, e acredito que ainda trabalha para objetos dinâmicos em AS3. Eu acho que as propriedades que ele vai mostrar é mais limitado em objetos não dinâmicos.

Answer 2

flash.utils.describeType(value:*) também lhe dará uma lista de propriedades em um objeto.

Answer 3

Você provavelmente está procurando

ObjectUtil.getClassInfo(object) 

, consulte:

http: // livedocs. adobe.com/flex/3/langref/mx/utils/ObjectUtil.html#getClassInfo%28%29

Esteja ciente de que há um bug nele que faz com que XML tratar como um tipo de dados não dinâmica. Mais sobre o bug em: bugs.adobe.com/jira/browse/SDK-17712

Answer 4

for-em obras para dinâmico somente objetos. Para objetos digitados você precisará usar algum tipo de reflexão para obter nomes de propriedade (por exemplo http: //www.as3commons.org/as3-commons-reflect/index.html )

/ Andrei.

Answer 5

para mim foi útil apenas isto:

trace('obj = '+getProperties(obj));

        public static function getProperties(obj:*):String  {
            var p:*;
            var res:String = '';
            var val:String;
            var prop:String;
            for (p in obj) {
                prop = String(p);
                if (prop && prop!=='' && prop!==' ') {
                    val = String(obj[p]);
                    if (val.length>10) val = val.substr(0,10)+'...';
                    res += prop+':'+val+', ';
                }
            }
            res = res.substr(0, res.length-2);
            return res;
        }

e você terá algo parecido com isto:

obj = m:email@ra..., r:true

Answer 6

// this method will work for retrieving properties of a *non-dynamic* (typed) object

// @return - all object properties
public function getProperties(_obj : *) : Array
{
        var _description : XML = describeType(_obj);
        var _properties : Array = new Array();
        for each (var prop:XML in _description.accessor)
        {
                var _property : Object = new Object();
                _property.name = String(prop.@name);
                _property.type = String(simple_type(prop.@type));
                _property.access = String(prop.@access);
                _property.declaredBy = String(prop.@declaredBy);
                try
                {
                   _property.value = _obj[_property.name];
                }
                catch (e : Error)
                {
                   _property.value = "";
                }
                _properties.push(_property)
        }
        _properties.sortOn("name");
        return _properties;
}

// better format for object class information
private function simple_type(_type : String) : String
{
        var lastIndex : int = _type.lastIndexOf("::");
        _type = lastIndex > 0 ? _type.substr(lastIndex + 2) : _type;
        return _type;
}

Answer 7

Você pode usar um para .. em loop para obter os nomes de propriedades, ou um para cada .. em loop para obter o valor das propriedades ...

for( var o : * in object){
    trace( o + " = " + object[o] );
}
/************* OR ******************/
for each( var o : * in object ){
    trace( "object has property: " + o );
}

Answer 8

Isso também irá ajudá-lo ..
1. Para Loop - irá trabalhar com base no índice
2. para cada - chamada recursiva até o comprimento
3. Para in - usado para ler os valores de propriedade

     for( var obj : String in objectData ) //here objectData is your object
     {
        trace( "Object Name Is : " + obj );
        var data : Object = objectData[obj]; //here we get the object value by using the property name
        trace( "Value Is : " + data ); //Converts object to string
     }