프로그래밍 방식으로 IIS에 Silverlight Mime 유형을 등록하십시오
-
22-08-2019 - |
문제
Silverlight 응용 프로그램 용 설치 프로그램을 작성하고 있으며 IIS 용 .xap 확장자를 자동으로 등록 할 수 있기를 원합니다. 레지스트리를 편집하지 않고 이것을 달성 할 수있는 방법이 있습니까? 그렇지 않다면 어떤 레지스트리 항목을 만들어야합니까? 감사!
해결책
- start-> run inetmgr (시작 IIS 관리 콘솔 시작)
- MIME 유형을 클릭하십시오
- ADD를 클릭하십시오
- 확인을 누릅니다
또는이 코드를 텍스트 파일로 저장하고 서버에서 실행할 수 있습니다.
AddMimeType.vbs
Dim VPath
'This changes setting at machine level, you may change it to a different path
VPath = "IIS://localhost/MimeMap"
'Add/Update the type for DLR language extension
UpdateMime ".xap", "application/x-silverlight-app"
'Search for the given extension and update its type
'when not found, add it into the collection
Sub UpdateMime(Extension, NewType)
Dim LocalMimeMap, MimeMap, MMItem, aMimeMapNew()
Dim i
i = 0
Const ADS_PROPERTY_CLEAR = 1
Const ADS_PROPERTY_UPDATE = 2
Set LocalMimeMap = GetObject(VPath)
MimeMap = LocalMimeMap.GetEx("MimeMap")
Dim found
found = False
For Each MMItem In MimeMap
ReDim Preserve aMimeMapNew(i)
Set aMimeMapNew(i) = CreateObject("MimeMap")
aMimeMapNew(i).Extension = MMItem.Extension
If MMItem.Extension = Extension Then
found = True
MsgBox("Update type of extension " + MMItem.Extension + " from " + MMItem.MimeType + " to " + NewType)
aMimeMapNew(i).MimeType = NewType
Else
aMimeMapNew(i).MimeType = MMItem.MimeType
End If
i = i + 1
Next
If found Then
LocalMimeMap.PutEx ADS_PROPERTY_UPDATE, "MimeMap", aMimeMapNew
LocalMimeMap.SetInfo
Else
MsgBox("Add new extension " + Extension + " with type " + NewType)
AddMime Extension, NewType
End If
End Sub
Sub AddMime(ExtensionToAdd, MimeTypeToAdd)
Dim LocalMimeMap, MimeMap
Dim i
Const ADS_PROPERTY_UPDATE = 2
Set LocalMimeMap = GetObject(VPath)
MimeMap = LocalMimeMap.GetEx("MimeMap")
i = UBound(MimeMap)+1
Redim Preserve MimeMap(i)
Set MimeMap(i) = CreateObject("MimeMap")
MimeMap(i).Extension = ExtensionToAdd
MimeMap(i).MimeType = MimeTypeToAdd
LocalMimeMap.PutEx ADS_PROPERTY_UPDATE,"MimeMap",MimeMap
LocalMimeMap.SetInfo
End Sub
제휴하지 않습니다 StackOverflow