Vbscript Ausgang Konsole
Frage
Was ist der Befehl oder der schnellste Weg, um Ergebnisse zu Ausgabe VBSript zu trösten?
Lösung
Sie bedeuten:
Wscript.Echo "Like this?"
Wenn Sie ausführen, die unter wscript.exe
(der Standard-Handler für die Erweiterung VBS, so was Sie bekommen, wenn Sie das Skript doppelklicken Sie) Ein „MessageBox“ Dialog mit Ihrem Text in es. Wenn Sie, dass unter cscript.exe
ausgeführt werden Sie Ausgabe in der Konsole-Fenster.
Andere Tipps
Ich weiß, das vor einer Weile war aber vielleicht hilft anderen. Es wurde auf Dragon-IT Scripts gefunden und Code-Repository .
Sie können dies mit dem folgenden und bleiben von den cscript / wscript Unterschiede entfernt und ermöglicht es Ihnen, die gleiche Konsole Ausgabe zu erhalten, dass eine Batch-Datei haben. Dies kann helfen, wenn Ihr VBS aus einer Batch-Datei und Notwendigkeit nannte es nahtlos aussehen zu lassen.
Set fso = CreateObject ("Scripting.FileSystemObject")
Set stdout = fso.GetStandardStream (1)
Set stderr = fso.GetStandardStream (2)
stdout.WriteLine "This will go to standard output."
stderr.WriteLine "This will go to error output."
Sie müssen nur Kraft cscript statt wscript. Ich benutze immer diese Vorlage. Die Funktion ForceConsole () wird Ihre vbs in Cscript ausführen, auch Sie schöne alias haben und Scan-Text zu drucken.
Set oWSH = CreateObject("WScript.Shell")
vbsInterpreter = "cscript.exe"
Call ForceConsole()
Function printf(txt)
WScript.StdOut.WriteLine txt
End Function
Function printl(txt)
WScript.StdOut.Write txt
End Function
Function scanf()
scanf = LCase(WScript.StdIn.ReadLine)
End Function
Function wait(n)
WScript.Sleep Int(n * 1000)
End Function
Function ForceConsole()
If InStr(LCase(WScript.FullName), vbsInterpreter) = 0 Then
oWSH.Run vbsInterpreter & " //NoLogo " & Chr(34) & WScript.ScriptFullName & Chr(34)
WScript.Quit
End If
End Function
Function cls()
For i = 1 To 50
printf ""
Next
End Function
printf " _____ _ _ _____ _ _____ _ _ "
printf "| _ |_| |_ ___ ___| |_ _ _ _| | | __|___ ___|_|___| |_ "
printf "| | | '_| . | | --| | | | . | |__ | _| _| | . | _|"
printf "|__|__|_|_,_|___|_|_|_____|_____|___| |_____|___|_| |_| _|_| "
printf " |_| v1.0"
printl " Enter your name:"
MyVar = scanf
cls
printf "Your name is: " & MyVar
wait(5)
Ich kam in diesem Post und ging zu einem Ansatz zurück, dass ich einige Zeit verwendet, vor denen @ MadAntrax der ähnlich ist.
Der Hauptunterschied ist, dass es eine VBScript benutzerdefinierte Klasse verwendet, die gesamte Logik umwickeln, um CScript zum Schalten und Text auf die Konsole ausgibt, so dass es das Hauptskript cleaner etwas macht.
Dies setzt voraus, dass Ihr Ziel ist es auf die Konsole zu streamen, anstatt Ausgang geht mit zu Meldungsfeldern.
Die cconsole Klasse ist unten. Um es zu nutzen, umfasst die komplette Klasse am Ende des Skripts, und es dann instanziiert gleich am Anfang des Skripts. Hier ein Beispiel:
Option Explicit
'// Instantiate the console object, this automatically switches to CSCript if required
Dim CONS: Set CONS = New cCONSOLE
'// Now we can use the Consol object to write to and read from the console
With CONS
'// Simply write a line
.print "CSCRIPT Console demo script"
'// Arguments are passed through correctly, if present
.Print "Arg count=" & wscript.arguments.count
'// List all the arguments on the console log
dim ix
for ix = 0 to wscript.arguments.count -1
.print "Arg(" & ix & ")=" & wscript.arguments(ix)
next
'// Prompt for some text from the user
dim sMsg : sMsg = .prompt( "Enter any text:" )
'// Write out the text in a box
.Box sMsg
'// Pause with the message "Hit enter to continue"
.Pause
End With
'= =========== End of script - the cCONSOLE class code follows here
Hier ist der Code für die cconsole Klasse
CLASS cCONSOLE
'= =================================================================
'=
'= This class provides automatic switch to CScript and has methods
'= to write to and read from the CSCript console. It transparently
'= switches to CScript if the script has been started in WScript.
'=
'= =================================================================
Private oOUT
Private oIN
Private Sub Class_Initialize()
'= Run on creation of the cCONSOLE object, checks for cScript operation
'= Check to make sure we are running under CScript, if not restart
'= then run using CScript and terminate this instance.
dim oShell
set oShell = CreateObject("WScript.Shell")
If InStr( LCase( WScript.FullName ), "cscript.exe" ) = 0 Then
'= Not running under CSCRIPT
'= Get the arguments on the command line and build an argument list
dim ArgList, IX
ArgList = ""
For IX = 0 to wscript.arguments.count - 1
'= Add the argument to the list, enclosing it in quotes
argList = argList & " """ & wscript.arguments.item(IX) & """"
next
'= Now restart with CScript and terminate this instance
oShell.Run "cscript.exe //NoLogo """ & WScript.ScriptName & """ " & arglist
WScript.Quit
End If
'= Running under CScript so OK to continue
set oShell = Nothing
'= Save references to stdout and stdin for use with Print, Read and Prompt
set oOUT = WScript.StdOut
set oIN = WScript.StdIn
'= Print out the startup box
StartBox
BoxLine Wscript.ScriptName
BoxLine "Started at " & Now()
EndBox
End Sub
'= Utility methods for writing a box to the console with text in it
Public Sub StartBox()
Print " " & String(73, "_")
Print " |" & Space(73) & "|"
End Sub
Public Sub BoxLine(sText)
Print Left(" |" & Centre( sText, 74) , 75) & "|"
End Sub
Public Sub EndBox()
Print " |" & String(73, "_") & "|"
Print ""
End Sub
Public Sub Box(sMsg)
StartBox
BoxLine sMsg
EndBox
End Sub
'= END OF Box utility methods
'= Utility to center given text padded out to a certain width of text
'= assuming font is monospaced
Public Function Centre(sText, nWidth)
dim iLen
iLen = len(sText)
'= Check for overflow
if ilen > nwidth then Centre = sText : exit Function
'= Calculate padding either side
iLen = ( nWidth - iLen ) / 2
'= Generate text with padding
Centre = left( space(iLen) & sText & space(ilen), nWidth )
End Function
'= Method to write a line of text to the console
Public Sub Print( sText )
oOUT.WriteLine sText
End Sub
'= Method to prompt user input from the console with a message
Public Function Prompt( sText )
oOUT.Write sText
Prompt = Read()
End Function
'= Method to read input from the console with no prompting
Public Function Read()
Read = oIN.ReadLine
End Function
'= Method to provide wait for n seconds
Public Sub Wait(nSeconds)
WScript.Sleep nSeconds * 1000
End Sub
'= Method to pause for user to continue
Public Sub Pause
Prompt "Hit enter to continue..."
End Sub
END CLASS
Es gibt fünf Möglichkeiten zur Ausgabe von Text auf die Konsole:
Dim StdOut : Set StdOut = CreateObject("Scripting.FileSystemObject").GetStandardStream(1)
WScript.Echo "Hello"
WScript.StdOut.Write "Hello"
WScript.StdOut.WriteLine "Hello"
Stdout.WriteLine "Hello"
Stdout.Write "Hello"
WScript.Echo Willen auf der Konsole, aber nur, wenn das Skript gestartet wird mit cscript.exe. Es wird ausgegeben, um Meldungsfelder gestartet, wenn wscript.exe verwendet wird.
WScript.StdOut.Write und WScript.StdOut.WriteLine wird immer auf der Konsole.
StdOut.Write und StdOut.WriteLine wird auch immer auf der Konsole. Es erfordert zusätzliche Objekterstellung, aber es ist ca. 10% schneller als WScript.Echo.