IE 9 не принимает SendKeys
-
11-12-2019 - |
Вопрос
я разместил на IE 9 не принимает SendKeys для загрузки файла, но эта проблема достаточно отделена от полученного мной ответа, чтобы оправдать еще один вопрос.Моя проблема в том, что я не могу заставить IE 9 принимать какие-либо из SendKeys
.я пытался Листать вниз, Вкладка, Все Ф# ключи, и ни один из них не работает.
Вот код, который я использую:
Dim ie As Object
'This creates the IE object
Sub initializeIE()
'call this subprocedure to start internet explorer up
Set ie = CreateObject("internetexplorer.application")
pos = 1
End Sub
'Initialize the class object
Private Sub Class_Initialize()
initializeIE
End Sub
Function followLinkByText(thetext As String) As Boolean
'clicks the first link that has the specified text
Dim alink As Variant
'Loops through every anchor in html document until specified text is found
' then clicks the link
For Each alink In ie.document.Links
If alink.innerHTML = thetext Then
alink.Click
'waitForLoad
Application.Wait Now + TimeValue("00:00:01")
Application.SendKeys "{PGDN}", True
Application.SendKeys "{PGUP}", True
'I've also tried calling it without Application before it
SendKeys "{F1}", True
SendKeys "{F2}", True
'Etc... Each of these not being received by IE 9
followLinkByText = True
Exit Function
End If
Next
End Function
Я в полной растерянности, потому что кажется, что большинство форумов или руководств не делают ничего особенного для IE 9.Объект IE создается в модуле класса и инициализируется в Class_Initialize
суб.Я не уверен, поможет ли это кому-нибудь, но я действительно понятия не имею, почему это не работает, и буду очень признателен за любую помощь в том, как отправлять ключи в IE.
Решение
На самом деле это копия мой ответ к этот вопрос, но это все еще может применяться.
Активно ли окно IE, когда вы пытаетесь SendKeys
?Если нет, это объясняет, что он не работает.
Чтобы активировать окно:
В начале вашего модуля поместите следующую строку кода:
Public Declare Function SetForegroundWindow Lib "user32" (ByVal HWND As Long) As Long
Это позволит вам получить доступ к SetForegroundWindow
функция встроена в Windows.
В своем коде при взаимодействии с объектом IE запишите HWND для этого окна следующим образом:
Dim HWNDSrc As Long
HWNDSrc = ie.HWND
Затем, после загрузки страницы, используйте это для продолжения, а затем отправьте ключевые действия:
SetForegroundWindow HWNDSrc
Однако в этом может не быть необходимости, в зависимости от того, как вы взаимодействуете с IE.Другими словами, если вам не нужно видеть/прикасаться к окну (вы делаете это для SendKeys
), вы по-прежнему можете взаимодействовать, используя объект в коде.
Теперь я вижу, что вы используете Application.Wait после щелчка, но это не гарантирует загрузку страницы IE.Эта функция должна помочь в этом.
Public Sub WaitForIE(myIEwindow As InternetExplorer, HWND As Long, WaitTime As Integer)
' Add pauses/waits so that window action can actually
' begin AND finish before trying to read from myIEWindow.
' myIEWindow is the IE object currently in use
' HWND is the HWND for myIEWindow
' The above two variables are both used for redundancy/failsafe purposes.
' WaitTime is the amount of time (in seconds) to wait at each step below.
' This is variablized because some pages are known to take longer than
' others to load, and some pages with frames may be partially loaded,
' which can incorrectly return an READYSTATE_COMPLETE status, etc.
Dim OpenIETitle As SHDocVw.InternetExplorer
Application.Wait DateAdd("s", WaitTime, Now())
Do Until myIEwindow.ReadyState = READYSTATE_COMPLETE
' Wait until IE is done loading page and/or user actions are done.
Loop
Application.Wait DateAdd("s", WaitTime, Now())
While myIEwindow.Busy
DoEvents ' Wait until IE is done loading page and/or user actions are done.
Wend
On Error Resume Next
' Make sure our window still exists and was not closed for some reason...
For Each OpenIETitle In objShellWindows
If OpenIETitle.HWND = HWND Then
If Err.Number = 0 Then
Set myIEwindow = OpenIETitle
Exit For
Else
Err.Clear
End If
End If
Next OpenIETitle
On Error GoTo 0
End Sub
Рискуя быть многословным, я обновил ваш код этими предложениями...
' Added by Gaffi
Public Declare Function SetForegroundWindow Lib "user32" (ByVal HWND As Long) As Long
Dim HWNDSrc As Long
Dim ie As Object
'This creates the IE object
Sub initializeIE()
'call this subprocedure to start internet explorer up
Set ie = CreateObject("internetexplorer.application")
' Added by Gaffi
HWNDSrc = ie.HWND
pos = 1
End Sub
'Initialize the class object
Private Sub Class_Initialize()
initializeIE
End Sub
Function followLinkByText(thetext As String) As Boolean
'clicks the first link that has the specified text
Dim alink As Variant
'Loops through every anchor in html document until specified text is found
' then clicks the link
For Each alink In ie.document.Links
If alink.innerHTML = thetext Then
alink.Click
'waitForLoad
' Added by Gaffi
WaitForIE ie, HWNDSrc, 1
SetForegroundWindow HWNDSrc
'Application.Wait Now + TimeValue("00:00:01")
Application.SendKeys "{PGDN}", True
Application.SendKeys "{PGUP}", True
'I've also tried calling it without Application before it
SendKeys "{F1}", True
SendKeys "{F2}", True
'Etc... Each of these not being received by IE 9
followLinkByText = True
Exit Function
End If
Next
End Function