Как сбросить несколько таблиц с общим префиксом в один запрос?
-
16-10-2019 - |
Вопрос
Я использую Microsoft SQL Server 2008. Мой вопрос: как бросить несколько таблиц с общим префиксом в один запрос?
что -то вроде этого имена таблиц:
LG_001_01_STLINE,
LG_001_02_STFICHE
Решение
Вы можете создать строку, используя представления каталога, например:
DECLARE @sql NVARCHAR(MAX) = N'';
SELECT @sql += '
DROP TABLE '
+ QUOTENAME(s.name)
+ '.' + QUOTENAME(t.name) + ';'
FROM sys.tables AS t
INNER JOIN sys.schemas AS s
ON t.[schema_id] = s.[schema_id]
WHERE t.name LIKE 'LG_001%';
PRINT @sql;
-- EXEC sp_executesql @sql;
Конечно, есть потенциальные gatchas, например, если эти таблицы имеют отношения иностранных ключей, вам нужно сначала бросить их, либо договориться о выводе, чтобы отбросить таблицы в определенном порядке.
Чтобы просто получить список таблиц, используйте:
SELECT s.name, t.name
FROM sys.tables AS t
INNER JOIN sys.schemas AS s
ON t.[schema_id] = s.[schema_id]
WHERE t.name LIKE 'LG_001%';
Другие советы
Я запустил этот запрос, а затем вставил результаты обратно в окно запроса, чтобы отбросить все таблицы:
SELECT 'DROP TABLE ' + NAME from sys.tables
ORDER BY NAME
Если вы хотите удалить все таблицы, но держите те с именами, которые начались с A, B, C или D:
SELECT 'DROP TABLE ' + NAME from sys.tables
WHERE NAME NOT LIKE '[ABCD]%'
GROUP BY NAME
Это позволяет вам удалить гораздо большее количество таблиц.
declare
@cursor as cursor,
@FTABLE as varchar(500)
set @cursor = CURSOR FOR
select 'drop table ' + NAME + ';'
from sys.tables
where not SUBSTRING(NAME,10,3) in
(
'310',
'311',
'312',
'313',
'314',
'320',
'321',
'322'
)
open @cursor
fetch next from @cursor into @FTABLE
while (@@FETCH_STATUS =0)
begin
exec(@FTABLE)
print @FTABLE
fetch next from @cursor into @FTABLE
end
close @cursor
deallocate @cursor
Мне нравится этот, который я написал:
DECLARE @chv_LG001_TableName nvarchar (100)
DECLARE @chv_DROP_LG001_Tables nvarchar(100)
DECLARE @chv_LG001_Table_Count int
SET @chv_LG001_Table_Count = (SELECT count(OBJECT_NAME(id))
FROM SYSINDEXES
WHERE OBJECTPROPERTY(id,'isUserTable')=1 AND indid < 2
and OBJECT_NAME(id) like 'LG_001%')
IF @chv_LG001_Table_Count > 0
BEGIN
DECLARE Drop_LG001_Tables_Cursor CURSOR FOR
-- This query will give you the table list you are wanting
SELECT OBJECT_NAME(id)
FROM SYSINDEXES
WHERE OBJECTPROPERTY(id,'isUserTable')=1 AND indid < 2
and OBJECT_NAME(id) like 'LG_001%'
OPEN Drop_LG001_Tables_Cursor
FETCH NEXT FROM Drop_LG001_Tables_Cursor INTO @chv_LG001_TableName
WHILE @@FETCH_STATUS = 0
BEGIN
SET @chv_DROP_LG001_Tables = 'DROP TABLE ' + '[' + @chv_LG001_TableName + ']'
--Print @chv_DROP_LG001_Tables
-- Uncomment the next line when you are ready because it WILL clear out these tables.
--EXEC sp_executesql @chv_DROP_LG001_Tables
FETCH NEXT FROM Drop_LG001_Tables_Cursor
INTO @chv_LG001_TableName
END
CLOSE Drop_LG001_Tables_Cursor
DEALLOCATE Drop_LG001_Tables_Cursor
END
Это можно сделать с помощью execute
следующим образом:
declare @sql1 nvarchar(max)
SELECT @sql1 =
STUFF(
(
select ' drop table dbo.[' + name + ']'
FROM sys.sysobjects AS sobjects
WHERE (xtype = 'U') AND (name LIKE 'GROUP_BASE_NEW_WORK_%')
for xml path('')
),
1,1,'')
execute sp_executesql @sql1
SELECT s.name, t.name
FROM sys.tables AS t
INNER JOIN sys.schemas AS s
ON t.[schema_id] = s.[schema_id]
WHERE t.name LIKE 'LG_001%';
Запустите выше запроса и сохраните результаты в CSV. Затем откройте этот CSV в блокноте. Затем сделайте Ctrl+H, чтобы заменить схему на схему Drop Table, которая даст вам все запросы Drop, скопируйте и вставьте этот большой SQL в свой инструмент SQL и выполните
Если ваши результаты
myschema.table1
myschema.table2
После замены это будет выглядеть так
DROP TABLE MYSCHEMA.TABLE1
DROP TABLE MYSCHEMA.TABLE2