XPath selezionare nodo con spazio dei nomi

Question

E 'un vbproj e si presenta come questo

<Project DefaultTargets="Build" xmlns="http://schemas.microsoft.com/developer/msbuild/2003">
    <PropertyGroup>
        <ProjectGuid>15a7ee82-9020-4fda-a7fb-85a61664692d</ProjectGuid>

tutto quello che voglio ottenere è la ProjectGuid ma non funziona quando un namespace è lì ...

 Dim xmlDoc As New XmlDocument()
 Dim filePath As String = Path.Combine(mDirectory, name + "\" + name + ".vbproj")
 xmlDoc.Load(filePath)
 Dim value As Object = xmlDoc.SelectNodes("/Project/PropertyGroup/ProjectGuid")

cosa posso fare per risolvere questo problema?

Answer 1

Il modo migliore per fare le cose come questo (secondo me) è quello di creare un gestore di spazio dei nomi. Questo può essere usato chiamando SelectNodes per indicare che gli URL degli spazi dei nomi sono collegati a quali prefissi. Io di solito ha installato una proprietà statica che restituisce un'istanza adeguata come questo (che è C #, si dovrà tradurre):

private static XmlNamespaceManager _nsMgr;
public static XmlNamespaceManager NsMgr
{
  get
  {
    if (_nsMgr == null)
    {
      _nsMgr = new XmlNamespaceManager(new NameTable());
      _nsMgr.AddNamespace("msb", "http://schemas.microsoft.com/developer/msbuild/2003");
    }
    return _nsMgr;
  }
}

I includere un solo spazio dei nomi qui, ma si potrebbe avere di più. Quindi è possibile selezionare dal documento in questo modo:

Dim value As Object = xmlDoc.SelectNodes("/msb:Project/msb:PropertyGroup/msb:ProjectGuid", NsMgr)

Si noti che tutti gli elementi sono nello spazio dei nomi specificato.

Answer 2

probabilmente sarei propenso ad andare con * soluzione namespace di Bartek, ma una soluzione generale XPath è:

//*[local-name()='ProjectGuid']

** in quanto la risposta di Bartek è scomparso, vi consiglio di Teun (che in realtà è più approfondita) *

Answer 3

Questo problema è stato qui diversi volte già .

In entrambi i lavori con le espressioni XPath namespace-agnostico (non raccomandato per la sua goffaggine e il potenziale per le partite falsi positivi - <msb:ProjectGuid> e <foo:ProjectGuid> sono gli stessi per questa espressione):

//*[local-name() = 'ProjectGuid']

o fare la cosa giusta e utilizza un XmlNamespaceManager per registrare il namespace URI in modo da poter includere un prefisso dello spazio dei nomi nella vostra XPath:

Dim xmlDoc As New XmlDocument()
xmlDoc.Load(Path.Combine(mDirectory, name, name + ".vbproj"))

Dim nsmgr As New XmlNamespaceManager(xmlDoc.NameTable)
nsmgr.AddNamespace("msb", "http://schemas.microsoft.com/developer/msbuild/2003")

Dim xpath As String = "/msb:Project/msb:PropertyGroup/msb:ProjectGuid"
Dim value As Object = xmlDoc.SelectNodes(xpath, nsmgr)

Answer 4

E 'necessario solo per registrare questo namespace XML e associare con un prefisso, per rendere il lavoro di query. Creare e passare un gestore di spazio dei nomi, come secondo parametro nella scelta dei nodi:

Dim ns As New XmlNamespaceManager ( xmlDoc.NameTable )
ns.AddNamespace ( "msbuild", "http://schemas.microsoft.com/developer/msbuild/2003" )
Dim value As Object = xmlDoc.SelectNodes("/msbuild:Project/msbuild:PropertyGroup/msbuild:ProjectGuid", ns)

Answer 5

Un modo è quello di utilizzare le estensioni + NameSpaceManager.
Codice è in VB, ma è davvero facile da tradurre in C #.

Imports System.Xml
Imports System.Runtime.CompilerServices

Public Module Extensions_XmlHelper

    'XmlDocument Extension for SelectSingleNode
    <Extension()>
    Public Function _SelectSingleNode(ByVal XmlDoc As XmlDocument, xpath As String) As XmlNode
        If XmlDoc Is Nothing Then Return Nothing

        Dim nsMgr As XmlNamespaceManager = GetDefaultXmlNamespaceManager(XmlDoc, "x")
        Return XmlDoc.SelectSingleNode(GetNewXPath(xpath, "x"), nsMgr)
    End Function

    'XmlDocument Extension for SelectNodes
    <Extension()>
    Public Function _SelectNodes(ByVal XmlDoc As XmlDocument, xpath As String) As XmlNodeList
        If XmlDoc Is Nothing Then Return Nothing

        Dim nsMgr As XmlNamespaceManager = GetDefaultXmlNamespaceManager(XmlDoc, "x")
        Return XmlDoc.SelectNodes(GetNewXPath(xpath, "x"), nsMgr)
    End Function


    Private Function GetDefaultXmlNamespaceManager(ByVal XmlDoc As XmlDocument, DefaultNamespacePrefix As String) As XmlNamespaceManager
        Dim nsMgr As New XmlNamespaceManager(XmlDoc.NameTable)
        nsMgr.AddNamespace(DefaultNamespacePrefix, XmlDoc.DocumentElement.NamespaceURI)
        Return nsMgr
    End Function

    Private Function GetNewXPath(xpath As String, DefaultNamespacePrefix As String) As String
        'Methode 1: The easy way
        Return xpath.Replace("/", "/" + DefaultNamespacePrefix + ":")

        ''Methode 2: Does not change the nodes with existing namespace prefix
        'Dim Nodes() As String = xpath.Split("/"c)
        'For i As Integer = 0 To Nodes.Length - 1
        '    'If xpath starts with "/", don't add DefaultNamespacePrefix to the first empty node (before "/")
        '    If String.IsNullOrEmpty(Nodes(i)) Then Continue For
        '    'Ignore existing namespaces prefixes
        '    If Nodes(i).Contains(":"c) Then Continue For
        '    'Add DefaultNamespacePrefix
        '    Nodes(i) = DefaultNamespacePrefix + ":" + Nodes(i)
        'Next
        ''Create and return then new xpath
        'Return String.Join("/", Nodes)
    End Function

End Module

E per usarlo:

Imports Extensions_XmlHelper

......
Dim FileXMLTextReader As New XmlTextReader(".....")
FileXMLTextReader.WhitespaceHandling = WhitespaceHandling.None
Dim xmlDoc As XmlDocument = xmlDoc.Load(FileXMLTextReader)
FileXMLTextReader.Close()
......
Dim MyNode As XmlNode = xmlDoc._SelectSingleNode("/Document/FirstLevelNode/SecondLevelNode")

Dim MyNode As XmlNodeList = xmlDoc._SelectNodes("/Document/FirstLevelNode/SecondLevelNode")

......

Answer 6

Perché non usare il // di ignorare il namespace:

Dim value As Object = xmlDoc.SelectNodes("//ProjectGuid")

// agisce carta selvaggio seguire attraverso tutto tra la radice e il nome del nodo successivo specificato (cioè ProjectGuid)